Arduino库教程-有线-SFR Ranger Reader

SRFxx Sonic Range Finder Reader
（SRFxx索尼测距仪读取器）

• 这个例子展示了如何通过I2C串行通信用Arduino的Wire库来读取一个Devantech公司的 SRFxx （超声波测距仪）。

• I2C协议涉及使用两线发送和接收数据：串行时钟引脚（SCL），Arduino或者Genuino主控板在一个规律的时间间隔的脉冲，和一个串行数据引脚（SDA），两个设备之间发送的数据。如时钟线从低到高的变化（称为时钟脉冲的上升沿），一个比特的信息——将会按顺序组成一个特定设备的地址和一个命令或者数据——从板上通过SDA线传输到I2C设备。当这个信息被发送（一个字节接一个字节），直到主控板在SCL上产生时序前，被调用的设备执行请求并通过同样的线和同样的时钟发送返回它的数据（如果有必要）到板上。

• 因为12C协议允许每个功能的设备有它自己唯一的地址，当主设备和从设备轮流在一个线上沟通，用上处理器的两个引脚，你的Arduino或Genuino开发板是可以和很多设备交流的。

硬件要求

• Arduino or Genuino Board
• Devantech SRFxx 测距仪 (典型如 SRF02, SRF08, or SRF10,点击比较)
• 100 uf 电容
• 连接线
• 面包板

电路

• 连接SRFxx上的SDA引脚到开发板上的模拟引脚pin 4，而SCL引脚连接到模拟引脚pin5。用5V为SRFxx供电，同时并联一个100uF的电容到测距仪，来减缓电力供应变化。

图由 Fritzing 绘制

原理图

样例代码

• 如果使用两SRFxxs 在同一行，你必须确保他们不共享相同的地址。再寻址测距仪的指令可以在下面的代码底部找到。

// I2C SRF10 or SRF08 Devantech Ultrasonic Ranger Finder
// by Nicholas Zambetti <http://www.zambetti.com>
// and James Tichenor <http://www.jamestichenor.net>

// Demonstrates use of the Wire library reading data from the
// Devantech Utrasonic Rangers SFR08 and SFR10

// Created 29 April 2006

// This example code is in the public domain.


#include <Wire.h>

void setup() {
  Wire.begin();                // join i2c bus (address optional for master)
  Serial.begin(9600);          // start serial communication at 9600bps
}

int reading = 0;

void loop() {
  // step 1: instruct sensor to read echoes
  Wire.beginTransmission(112); // transmit to device #112 (0x70)
  // the address specified in the datasheet is 224 (0xE0)
  // but i2c adressing uses the high 7 bits so it's 112
  Wire.write(byte(0x00));      // sets register pointer to the command register (0x00)
  Wire.write(byte(0x50));      // command sensor to measure in "inches" (0x50)
  // use 0x51 for centimeters
  // use 0x52 for ping microseconds
  Wire.endTransmission();      // stop transmitting

  // step 2: wait for readings to happen
  delay(70);                   // datasheet suggests at least 65 milliseconds

  // step 3: instruct sensor to return a particular echo reading
  Wire.beginTransmission(112); // transmit to device #112
  Wire.write(byte(0x02));      // sets register pointer to echo #1 register (0x02)
  Wire.endTransmission();      // stop transmitting

  // step 4: request reading from sensor
  Wire.requestFrom(112, 2);    // request 2 bytes from slave device #112

  // step 5: receive reading from sensor
  if (2 <= Wire.available()) { // if two bytes were received
    reading = Wire.read();  // receive high byte (overwrites previous reading)
    reading = reading << 8;    // shift high byte to be high 8 bits
    reading |= Wire.read(); // receive low byte as lower 8 bits
    Serial.println(reading);   // print the reading
  }

  delay(250);                  // wait a bit since people have to read the output :)
}


/*

// The following code changes the address of a Devantech Ultrasonic Range Finder (SRF10 or SRF08)
// usage: changeAddress(0x70, 0xE6);

void changeAddress(byte oldAddress, byte newAddress)
{
  Wire.beginTransmission(oldAddress);
  Wire.write(byte(0x00));
  Wire.write(byte(0xA0));
  Wire.endTransmission();

  Wire.beginTransmission(oldAddress);
  Wire.write(byte(0x00));
  Wire.write(byte(0xAA));
  Wire.endTransmission();

  Wire.beginTransmission(oldAddress);
  Wire.write(byte(0x00));
  Wire.write(byte(0xA5));
  Wire.endTransmission();

  Wire.beginTransmission(oldAddress);
  Wire.write(byte(0x00));
  Wire.write(newAddress);
  Wire.endTransmission();
}

*/

[Get Code]
更多

• Wire.begin()
• Wire.beginTransmission()
• Wire.endTransmission()
• Wire.send()
• Wire.RequestFrom()
• Wire.receive()
• Wire Library – Wire库的参考网页.
• Digital Potentiometer: 控制一个模拟设备AD5171数字电位器。
• Master Reader/Slave Writer: 编程两个Arduino板之间通过I2C交流，另外一个设置为主读从写（Master Reader/Slave Sender）。
• Master Writer/Slave receiver:编程两个Arduino板之间通过I2C交流，另外一个设置为主写从收（Master Writer/Slave Receiver）。
• SFR Ranger Reader: 通过I2C读取超声波测距仪接口。